@echo off
rem
rem Usage:
rem fetch North West South East
rem
rem where each parameter is in the format
rem
rem "Deg Min Sec Hem"
rem
rem Will fetch an area one degree of latitude and one degree of longitude
rem large, in chunks of 5x5 minutes, starting at lat, lon
rem This will work on the north-western quarter-spehre only
rem

setlocal enabledelayedexpansion

rem Customize these:

set FSET=F:\FSEarthTiles\FSEarthTiles.exe
set WorkFolder=F:\Work\Temp
set StepSize=5

:main
    set North=%~1
    set West=%~2
    set South=%~3
    set East=%~4

    set E=%East%
    call :Add "%E%" %StepSize%
    set W=%ToString%
    set LonHem=%Hem%

    :Lon
        call :IsGreaterOrEqual "%W%" "%West%"
        if %GreaterOrEqual% EQU 1 set W=%West%

        set S=%South%
        call :Add "%S%" %StepSize%
        set N=%ToString%
        set LatHem=%Hem%

        :Lat
            call :IsGreaterOrEqual "%N%" "%North%"
            if %GreaterOrEqual% EQU 1 set N=%North%

            if %LatHem%==N (
                if %LonHem%==W (
                    echo --south %S% --north %N% --east %E% --west %W%
                    start /wait %FSET% --south %S% --north %N% --east %E% --west %W% --zoom 1 --snap Tiles --fetch
                ) else (
                    echo --south %S% --north %N% --west %E% --east %W%
                    start /wait %FSET% --south %S% --north %N% --west %E% --east %W% --zoom 1 --snap Tiles --fetch
                )
            ) else (
                if %LonHem%==W (
                    echo --north %S% --south %N% --east %E% --west %W%
                    start /wait %FSET% --north %S% --south %N% --east %E% --west %W% --zoom 1 --snap Tiles --fetch
                ) else (
                    echo --north %S% --south %N% --west %E% --east %W%
                    start /wait %FSET% --north %S% --south %N% --west %E% --east %W% --zoom 1 --snap Tiles --fetch
                )
            )

            call :Add "%S%" %StepSize%
            set S=%ToString%
            call :Add "%N%" %StepSize%
            set N=%ToString%

            call :IsGreaterOrEqual "%S%" "%North%"
            if %GreaterOrEqual% EQU 1 goto EndLat

            goto :Lat
        :EndLat

        call :Add "%E%" %StepSize%
        set E=%ToString%
        call :Add "%W%" %StepSize%
        set W=%ToString%

        call :IsGreaterOrEqual "%E%" "%West%"
        if %GreaterOrEqual% EQU 1 goto EndLon

        goto :Lon
    :EndLon


    mkdir %WorkFolder%\Thumbnails
    move %WorkFolder%\*_Thumbnail.bmp Thumbnails
    ren %WorkFolder% "%South% %East% - %North% %West%"

goto :eof



:ToDegMinSec
    set Deg=%1
    set Min=%2
    set Sec=%3
    set Hem=%4
goto :eof



:ToString
    set ToString=%1 %2 %3 %4
goto :eof



rem Usage: call Add "Deg Min Sec Hem" AddMin

:Add
    call :ToDegMinSec %~1
    set AddMin=%2

    set /a Min=%Min% + %AddMin%
    if %Min% GEQ 60 (
        set /a Min=%Min% - 60
        set /a Deg=%Deg% + 1
        rem Don't even think about making Deg overflow! 
    )
    call :ToString %Deg% %Min% %Sec% %Hem%
goto :eof



rem Usage: call IsGreaterOrEqual "Deg1 Min1 Sec1 Hem1" "Deg2 Min2 Sec2 Hem2"
rem sets GreaterOrEqual=1 if Coord1 >= Coord2, 0 otherwise

:IsGreaterOrEqual
    set GreaterOrEqual=0

    call :ToDegMinSec %~1
    set Deg1=%Deg%
    set Min1=%Min%
    set Sec1=%Sec%
    set Hem1=%Hem%

    call :ToDegMinSec %~2
    set Deg2=%Deg%
    set Min2=%Min%
    set Sec2=%Sec%
    set Hem2=%Hem%

    if not %Hem1%==%Hem2% goto :eof

    if %Deg1% LSS %Deg2% goto :eof
    if %Deg1% GTR %Deg2% (
        set GreaterOrEqual=1
        goto :eof
    )

    if %Min1% LSS %Min2% goto :eof
    if %Min1% GTR %Min2% (
        set GreaterOrEqual=1
        goto :eof
    )

    if %Sec1% LSS %Sec2% goto :eof
    if %Sec1% GTR %Sec2% (
        set GreaterOrEqual=1
        goto :eof
    )

    echo PANIC: Control should never pass through here!
    exit

goto :eof

endlocal

@echo off
rem
rem compile srcfolder inffile dstfolder bglname
rem

setlocal enabledelayedexpansion

set Folder=%~f1
set InfFile=%~n2.inf
set TmpFile=%InfFile%.tmp
set DstFolder=%~f3
set BGLName=%~n4.bgl
set c=0

echo Folder = %Folder%
echo InfFile = %InfFile%
echo TmpFile = %TmpFile%
echo DstFolder = %DstFolder%
echo BGLName = %BGLName%

for %%f in (%Folder%\*.inf) do (
    set /a c=c+1
    echo [Source!c!] >> %TmpFile%
    echo Type = Custom >> %TmpFile%
    echo SourceDir = %Folder% >> %TmpFile%
    tail -n7 %%f >> %TmpFile%
    echo. >> %TmpFile%
)

echo [Source] >> %InfFile%
echo Type = MultiSource >> %InfFile%
echo NumberOfSources = !c! >> %InfFile%
echo. >> %InfFile%

type %TmpFile% >> %InfFile%

echo [Destination] >> %InfFile%
echo DestDir = %DstFolder% >> %InfFile%
echo DestBaseFileName = %BGLName% >> %InfFile%
echo BuildSeasons = 0 >> %InfFile%
echo UseSourceDimensions = 1 >> %InfFile%
echo CompressionQuality = 85 >> %InfFile%
echo LOD = Auto >> %InfFile%
echo SplitDirLOD = 2 >> %InfFile%
echo SplitFileLOD = 5 >> %InfFile%

del %TmpFile%

endlocal